@...GET TBROWSE
 Create a new TBrowse Get object and display it to the screen
------------------------------------------------------------------------------
 Syntax

     @ <nTop>, <nLeft>, <nBottom>, <nRight>
        GET <idVar>
        TBROWSE <oBrowse>
           [MESSAGE <cMessage>]
           [WHEN <lPreExpression>]
           [VALID <lPostExpression>]
           [SEND <msg>]
           [GUISEND <guimsg>]

 Arguments

     <nTop>, <nLeft>, <nBottom> and <nRight> specify the
     screen position for the TBrowse object.  Output which extends beyond the
     visible extent of the display is clipped and does not appear.

     GET <idVar> specifies the name of the variable associated with the
     GET.  Its value is neither queried nor modified by the Get system.  The
     GET is merely a mechanism used for integrating a TBrowse object into the
     @...GET/READ system.

     TBROWSE <oTBrowse> specifies a previously defined TBrowse object.

     MESSAGE <cMessage> specifies a character string that is displayed on
     the Get system's status bar line when the GET has input focus.
     Typically, it describes the anticipated contents or user response of the
     GET.  Refer to the READ command for details pertaining to the Get
     system's status bar.

     WHEN <lPreExpression> specifies an expression that must be satisfied
     before the cursor can enter the GET during a READ.  The expression can
     optionally be a code block.  The Get object is passed as a parameter to
     the code block.

     VALID <lPostExpression> specifies an expression that must be
     satisfied before the cursor can leave the GET during a READ.  The
     expression can optionally be a code block.  The Get object is passed as
     a parameter to the code block.

     SEND <msg> sends the specified message to the Get object.  <msg> is
     sent before the GET is displayed.  Any message can be sent, including
     method calls and instance variable assignments.  Method calls must
     include parentheses even if no arguments are passed.

     GUISEND <guimsg> can be used to send a message (such as the
     display() method) to a GUI object.  The GUI objects available in
     CA-Clipper are check boxes, list boxes, push buttons, and radio button
     groups.  To send a message to a non-GUI object, such as standard GETs
     and TBrowses, use the SEND clause.

 Examples

     .  This example demonstrates how to add a TBrowse object to a
        data entry screen:

        oTB := TBrowseDB( 10, 10, 15, 40 )
        oTB:AddColumn(tbColumnNew("Last Name",{||Customer->lName}))
        oTB:AddColumn(tbColumnNew("First Name",{||Customer->fName}))
        oTB:AddColumn(tbColumnNew("Phone",{||Customer->Phone}))
        uDummy := NIL
        @ 10, 10, 15, 40 GET uDummy TBROWSE oTB

 Files   Library is CLIPPER.LIB.