DBGOBOTTOM()
 Move to the last logical record
------------------------------------------------------------------------------
 Syntax

     DBGOBOTTOM() --> NIL

 Returns

     DBGOBOTTOM() always returns NIL.

 Description

     DBGOBOTTOM() moves to the last logical record in the current work area.

     DBGOBOTTOM() performs the same function as the standard GO BOTTOM
     command.  For more information, refer to the GO command.

 Notes

     .  Logical records: DBGOBOTTOM() operates on logical records.  If
        there is an active index, DBGOBOTTOM() moves to the last record in
        indexed order.  If a filter is set, only records which meet the
        filter condition are considered.

     .  Controlling order: If more than one index is active in the
        work area, the operation is performed using the controlling order as
        set by DBSETORDER() or the SET ORDER command.  For more information,
        refer to the SET ORDER command.

     .  Network environment: For a shared file on a network, moving to
        a different record may cause updates to the current record to become
        visible to other processes.  For more information, refer to the
        "Network Programming" chapter in the Programming and Utilities Guide.
        This function will not affect the locked status of any record.

 Examples

     .  The following example uses DBGOBOTTOM() to position the record
        pointer on the last logical record:

        cLast := "Winston"
        DBUSEAREA( .T., "DBFNTX", "Sales", "Sales", .T. )
        DBSETINDEX( "LASTNAME" )
        //
        Sales->( DBGOBOTTOM() )
        IF ( Sales->Last == "Winston" )
           IF RLOCK()
              Sales->( DBDELETE() )
              ? "Record deleted: ", Sales->( DELETED() )
           ELSE
              ? "Unable to lock record..."
           ENDIF
        END

 Files   Library is CLIPPER.LIB.